このQ&Aは役に立ちましたか?
年齢の表示を桁合わせする
2014/09/03 21:16
今日現在の年齢を表示したときに、”月”を二桁表示にする方法を教えてください。見た目を 〇〇歳〇〇ヶ月と表示したい。
下記のような表です。
式は '=DATEDIF(C5,$A$5,"y")&"歳"&DATEDIF(C5,$A$5,"ym")&"ヶ月" と作りました。
今日 氏名 生年月日 年齢
2014/9/4 aa S25.10.31 63歳10ヶ月
bb S58.8.10 31歳0ヶ月
cc H20.7.20 6歳1ヶ月
※OKWaveより補足:「富士通FMV」についての質問です。
質問者が選んだベストアンサー
No.1です。
補足の
>12ヶ月
>05ヶ月とはではなく
>12ヶ月
> 5ヶ月 とスペースにするのはどうしたらいいのでしょうか
について・・・
まず、フォントが「MS Pゴシック」のように「P」付きになっていれば
「MS ゴシック」等「P」がついていないフォントに設定してください。
そうした上で表示したいセルに
=DATEDIF(C5,$A$5,"y")&"歳"&IF(DATEDIF(C5,$A$5,"ym")<10," ","")&TEXT(DATEDIF(C5,$A$5,"ym"),"0ヶ月")
としてみてください。
※ 「P」付きフォント(プロポーショナルフォント)にするときっちり文字が揃いません。m(_ _)m
このQ&Aは役に立ちましたか?
この質問は投稿から一年以上経過しています。
解決しない場合、新しい質問の投稿をおすすめします。
その他の回答 (5件中 1~5件目)
=TEXT(DATEDIF(C5,A$5,"Y"),"0歳") & TEXT(DATEDIF(C5,A$5,"YM"),"?0ヶ月")
または
=(IF(C5="","",TEXT(DATEDIF(C5,A$5,"Y"),"0歳;;;") & TEXT(DATEDIF(C5,A$5,"YM"),"?0ヶ月"))
のようにして、セルを右寄せにしましょう。
お礼
2014/09/05 21:11
ありがとうございました。
皆様のお答を全部試してみました。
ありがとうございました。
上の式が私の作った式に近いので参考になりました
=TEXT(DATEDIF(C5,A$5,"Y"),"??歳") & TEXT(DATEDIF(C5,A$5,"YM"),"00ヶ月")
といった具合で。
お礼
2014/09/04 20:52
ありがとうございました。
色々な方法があるのですね・・・
皆様から頂いた回答ですべて試していました。
助かりました。
年齢も2桁になって良ければ、簡単に書けます。
=TEXT($A$5-C6,"y歳mmヶ月")
お礼
2014/09/04 20:55
ありがとうございました。
色々な方法があるのですね。
今回は年齢をそのまま使用したので、使いませんでしたが勉強になりました。
こんばんは!
>”月”を二桁表示にする方法を教えてください。
2桁表示するのは「月」だけでよい訳ですね?
表示したいセルに
=DATEDIF(C5,$A$5,"Y")&"歳"&TEXT(DATEDIF(C5,$A$5,"YM"),"00")&"ヶ月"
としてみてください。m(_ _)m
お礼
2014/09/04 21:00
この式が現在の式に一番近かったのでこれを利用させていただきました。
きれいに表示できました。ありがとうございました。
補足
2014/09/04 21:08
あのーーー
12ヶ月
05ヶ月とはではなく
12ヶ月
5ヶ月 とスペースにするのはどうしたらいいのでしょうか
教えてください。
お礼
2014/09/05 21:08
最初の質問の仕方がまずくて再度聞くことになってしまいました。
皆様の回答を参考にして、
=DATEDIF(C5,$A$5,"Y")&"歳"&TEXT(DATEDIF(C5,$A$5,"YM"),"00")&"ヶ月"
上の式の
”00” を ””?0”にしたら スペース5ヶ月 という風に表示できました
と安心してたらもっともっとたくさんの式があるのに刺激されました
全部試しました。楽しかったです。ありがとうございました。勉強になりました。
今回は私の頭で一番わかりやすい、上記式を使わせていただきます。
本当にありがとうございました。